01-50讲源码

以下为早期股票指标公式编写零基础视频教程50篇配套源码。

内容仅供参考学习，理性使用，不能作为投资依据。

欢迎加作者的工作QQ：3303566119

第1讲

---------
{DRAWKLINE(HIGH,OPEN,LOW,CLOSE);}
DRAWKLINE(H,O,L,C);
{开盘线:OPEN;}
{收盘线:CLOSE;}
最高价:HIGH;
最低价:LOW;
----------
成交量线:VOL;
-----------
开盘线:OPEN;
收盘线:CLOSE;
最高价:HIGH;
最低价:LOW;

第2讲

第3讲

五线:MA(CLOSE,5);
十线:MA(CLOSE,10);
二十线:MA(CLOSE,20);
六十线:MA(CLOSE,60);
半年线:MA(CLOSE,120);
年线:MA(CLOSE,250);
机动线:MA(CLOSE,N),COLOREBB7F0;

第4讲

五线:MA(CLOSE,5);
十线:MA(CLOSE,10);
二十线:MA(CLOSE,20);
六十线:MA(CLOSE,60);
半年线:MA(CLOSE,120);
年线:MA(CLOSE,250);
机动线:MA(CLOSE,N),COLOREBB7F0;

第5讲

涨幅:=C/REF(C,1)-1;
REF(涨幅,1)>0.0992;

第6讲

涨幅:=C/REF(C,1)-1;
选股1:REF(涨幅,1)>0.05 AND REF(涨幅,1)0.08,COLORFF00FF;

-------------
涨幅:=C/REF(C,1)-1;
XG:REF(涨幅,1)>0.05 AND REF(涨幅,1)<0.08;

第7讲

涨幅:=C/REF(C,1)-1;
{涨停:=涨幅>0.0992;}
大阳线:=涨幅>0.07;
EXIST(大阳线,N);

第8讲

涨幅:=C/REF(C,1)-1;
涨停:=涨幅>0.0992;
连板:=EVERY(涨停,3);
最近存在连板:EXIST(连板,2);

第9讲

DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
MACD金叉:=CROSS(DIF,DEA);

MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
均线5金叉10:=CROSS(MA5,MA10);

RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
KDJ金叉:=CROSS(J,K);

选股:MACD金叉 AND 均线5金叉10 AND KDJ金叉;

第10讲

DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
MACD金叉:=CROSS(DIF,DEA);

MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
均线5金叉10:=CROSS(MA5,MA10);

RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
KDJ金叉:=CROSS(J,K);

涨停:=C/REF(C,1)-1>0.0992;

选股:EXIST(MACD金叉,2) AND EXIST(均线5金叉10,2) AND EXIST(KDJ金叉,2) AND EXIST(涨停,10);

第11讲

收阳:=CLOSE>OPEN;
收涨:=CLOSE>REF(CLOSE,1);
五连阳:=EVERY(收阳,5);
五连涨:=EVERY(收涨,5);
XG:五连阳 AND 五连涨;

第12讲

{缩量:=VOL<REF(VOL,1);
调整:=CLOSE<OPEN AND CLOSE<REF(CLOSE,1);
XG:EVERY(缩量,4) AND EVERY(调整,4);}

放量:=VOL>REF(VOL,1);
上涨:=CLOSE>OPEN AND CLOSE>REF(CLOSE,1);
XG:EVERY(放量,4) AND EVERY(上涨,4);

第13讲

{倍量:=VOL/REF(VOL,1)>=2;
涨停:=C/REF(C,1)-1>0.0992;
二连板:=EVERY(涨停,2);
XG:倍量 AND 二连板;}

倍量:=VOL/REF(VOL,1)>=2;
涨停:=C/REF(C,1)-1>0.0992;
三连板:=EVERY(涨停,3);
XG:倍量 AND 三连板;

第14讲

MA30:MA(CLOSE,30),COLORWHITE;

红色条件:=MA30>=REF(MA30,1) AND C>MA30;
持股:IF(红色条件,MA30,DRAWNULL),COLORRED;

绿色条件:=MA30<REF(MA30,1) AND C<MA30;
持币:IF(绿色条件,MA30,DRAWNULL),COLORGREEN;

黄色条件:=(MA30>=REF(MA30,1) AND C<MA30) OR (MA30<REF(MA30,1) AND C>=MA30);
观望:IF(黄色条件,MA30,DRAWNULL),COLORYELLOW;

DRAWKLINE(H,O,L,C);

第15讲

MA30:MA(CLOSE,30),COLORWHITE;

红色条件:=MA30>=REF(MA30,1) AND C>MA30;
持股:IF(红色条件,MA30,DRAWNULL),COLORRED;

绿色条件:=MA30<REF(MA30,1) AND C<MA30;
持币:IF(绿色条件,MA30,DRAWNULL),COLORGREEN;

黄色条件:=(MA30>=REF(MA30,1) AND C<MA30) OR (MA30<REF(MA30,1) AND C>=MA30);
观望:IF(黄色条件,MA30,DRAWNULL),COLORYELLOW;

倍量:=VOL/REF(VOL,1)>=2;
涨停:=C/REF(C,1)-1>0.0992;
二连板:=EVERY(涨停,2);
条件:倍量 AND 二连板,NODRAW;

DRAWTEXT(条件,L,'倍量板')COLOR00FFFF;
DRAWICON(条件,H*1.035,32);

第16讲

MA30:MA(CLOSE,30),COLORWHITE;

红色条件:=MA30>=REF(MA30,1) AND C>MA30;
持股:IF(红色条件,MA30,DRAWNULL),COLORRED;

绿色条件:=MA30<REF(MA30,1) AND C<MA30;
持币:IF(绿色条件,MA30,DRAWNULL),COLORGREEN;

黄色条件:=(MA30>=REF(MA30,1) AND C<MA30) OR (MA30<REF(MA30,1) AND C>=MA30);
观望:IF(黄色条件,MA30,DRAWNULL),COLORYELLOW;

倍量:=VOL/REF(VOL,1)>=2;
涨停:=C/REF(C,1)-1>0.0992;
二连板:=EVERY(涨停,2);
条件:倍量 AND 二连板,NODRAW;

STICKLINE(条件,L,H,0,1)COLOR00FF00;
STICKLINE(条件,O,C,2.5,1)COLOR00FF00;

DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
MACD金叉:=CROSS(DIF,DEA);
STICKLINE(MACD金叉 AND C>O,L,H,0,1)COLOR00FFFF;
STICKLINE(MACD金叉 AND C>O,O,C,2.5,1)COLOR00FFFF;
STICKLINE(MACD金叉 AND C<O,L,H,0,0)COLOR00FFFF;
STICKLINE(MACD金叉 AND C<O,O,C,2.5,0)COLOR00FFFF;

STICKLINE(涨停 AND C>O,L,H,0,1)COLORFF00FF;
STICKLINE(涨停 AND C>O,O,C,2.5,1)COLORFF00FF;
STICKLINE(涨停 AND C=O,L,H,0,0)COLORFF00FF;
STICKLINE(涨停 AND C=O,O,C,2.5,0)COLORFF00FF;

第17讲

{N:0,50,5 M:0,50,5,设置参数}
N:=5; M:=5;
H1:=EMA(DCLOSE,5);
A1:=LLV(DCLOSE,5);
A2:=A1+1/CURRBARSCOUNT*N;
A3:=IF(CURRBARSCOUNTREF(A1,1),CONST(REF(A2,10)),A1);
A4:=MA(A3,10);
A5:=H1+1/CURRBARSCOUNT*M;
A6:=IF(CURRBARSCOUNTREF(A1,1),CONST(REF(A5,10)),A3);
A7:=MA(A6,10);L1:=LLV(L,10);
{DRAWBAND(A4,90,L1,RGB(35,135,35));}
{DRAWBAND(A7,90,A4,90);}
主力操作线:=MA(C,24),LINETHICK2,COLORLIMAGENTA;
操作线2:=MA(C,26),LINETHICK1,COLORLICYAN;
{DRAWKLINE(HIGH,OPEN,LOW,CLOSE);}
启动点:=(DCLOSE-REF(C,1))/REF(C,1)*100;
XG:CROSS(启动点,10);
{L3:IF(XG,O,L1*0.999),COLORYELLOW;}
{STICKLINE(XG,L3,L3,100,0);}
{DRAWTEXT(XG,L3,'买点'),COLORMAGENTA;};

第18讲

{高点:=HHV(H,250);
{XG:REF(H,1)=高点;}
{条件:=H=高点;
XG:EXIST(条件,5);}

低点:=LLV(L,250);
{XG:REF(L,1)=低点;}
条件:=L=低点;
XG:EXIST(条件,5);

第19讲

DRAWTEXT(CURRBARSCOUNT=5,H,'5')COLORYELLOW;
DRAWTEXT(CURRBARSCOUNT=8,H,'8')COLORYELLOW;
DRAWTEXT(CURRBARSCOUNT=13,H,'13')COLORYELLOW;
DRAWTEXT(CURRBARSCOUNT=21,H,'21')COLORYELLOW;

DRAWTEXT(CURRBARSCOUNT=20,MA3*0.98,'20日线')COLORFF00FF;
DRAWTEXT(CURRBARSCOUNT=1,MA4,'牛熊线')COLOR00FF00;

DRAWICON(CURRBARSCOUNT=13,L,44);
DRAWICON(CURRBARSCOUNT=21,L,34);

第20讲

MA5:MA(CLOSE,20);
上拐点:=MA5>=REF(MA5,1) AND REF(MA5,1)<REF(MA5,2);
DRAWICON(上拐点,L,34);

下拐点:=MA5<REF(MA5,1) AND REF(MA5,1)>=REF(MA5,2);
DRAWICON(下拐点,L,35);

第21讲

MA5:=MA(CLOSE,5);
MA8:=MA(CLOSE,8);
MA13:=MA(CLOSE,13);
MA21:=MA(CLOSE,21);
MA34:=MA(CLOSE,34);
空头:=MA21<MA34 AND MA13<MA21;
放量:=V/REF(V,1)>1.8;
XG:CROSS(C,MA5) AND CROSS(C,MA8) AND CROSS(C,MA13) AND CROSS(C,MA21) AND CROSS(C,MA34)
AND 空头 AND 放量;

第22讲

MA1:=MA(CLOSE,13);
MA2:=MA(CLOSE,21);

STICKLINE(MA1>=MA2,MA1,MA2,5,0)COLORYELLOW;
STICKLINE(MA1<MA2,MA1,MA2,5,0)COLORBLUE;

MA(CLOSE,5),COLORWHITE;

DRAWKLINE(H,O,L,C);

第23讲

实体大小:MAX(C,O)-MIN(C,O);

实体大小2:ABS(C-O);

振幅:(H-L)/REF(C,1);

{MAX(MAX(MAX(A,B),C),D)}
{MIN(MIN(A,B),C)};

第24讲

今涨停:=C/REF(C,1)>1.0992;
倒数第三日涨停:=REF(C,3)/REF(C,4)>1.0992;
倒数第一日阴跌:=REF(C,1)<REF(O,1) AND REF(C,1)<REF(C,2);
倒数第二日阴跌:=REF(C,2)<REF(O,2) AND REF(C,2)<REF(C,3);
情况1:=今涨停 AND 倒数第一日阴跌 AND 倒数第二日阴跌 AND 倒数第三日涨停 AND L/REF(C,3)<0.95 AND L>REF(L,3);

倒数第四日涨停:=REF(C,4)/REF(C,5)>1.0992;
情况2:=今涨停 AND 倒数第一日阴跌 AND 倒数第二日阴跌 AND 倒数第四日涨停 AND L/REF(C,4)<0.95 AND L>REF(L,4);

XG:情况1 OR 情况2;

第25讲

跳空:=LOW>REF(HIGH,1);
十字星:=ABS(CLOSE/OPEN-1)<0.02 AND CLOSE/REF(CLOSE,1)<1.0992 AND
H!=C AND H!=O AND L!=C AND L!=O;
XG:跳空 AND 十字星;

{XG:LOW>REF(HIGH,1) AND ABS(CLOSE/OPEN-1)<0.02 AND CLOSE/REF(CLOSE,1)<1.0992 AND
H!=C AND H!=O AND L!=C AND L!=O;}
{跳空幅度:=LOW>REF(HIGH,1) AND O/REF(C,1)>1.03;}
{配套代码25}

第26讲

DRAWKLINE(H,O,L,C);
MA5:MA(CLOSE,5),COLORFFFFFF;
上拐点:=MA5>REF(MA5,1) AND REF(MA5,1)<REF(MA5,2);
下拐点:=MA5<REF(MA5,1) AND REF(MA5,1)>REF(MA5,2);
DRAWNUMBER(上拐点,LLV(L,5),LLV(L,5)),COLORYELLOW;
DRAWNUMBER(下拐点,HHV(H,5),HHV(H,5)),COLORGREEN;
{配套代码26};

第27讲

MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
MA15:=MA(CLOSE,15);
MA20:=MA(CLOSE,20);
MA30:=MA(CLOSE,30);
MA40:=MA(CLOSE,40);
MA60:=MA(CLOSE,60);

MA5上扬:=MA5>REF(MA5,1);
MA10上扬:=MA10>REF(MA10,1);
MA15上扬:=MA15>REF(MA15,1);
MA20上扬:=MA20>REF(MA20,1);
MA30上扬:=MA30>REF(MA30,1);
MA40上扬:=MA40>REF(MA40,1);
MA60上扬:=MA60>REF(MA60,1);

MA30下降:=MA30<REF(MA30,1);
XG:MA5上扬 AND MA10上扬 AND MA15上扬 AND MA20上扬 AND MA30上扬 AND MA40上扬 AND MA60上扬 AND
EXIST(MA30下降,10);

{配套代码27};

第28讲

A:=MA(CLOSE,5);
B:=MA(CLOSE,10);
均线死叉:=CROSS(B,A);

DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
MACD:=(DIF-DEA)*2;
MACD金叉:=CROSS(DIF,DEA);

{MACD金叉以来，一直是红柱}

MACD金叉以来:=BARSLAST(MACD金叉);
XG:EVERY(MACD>0,MACD金叉以来) AND MACD金叉以来>=15 AND 均线死叉 AND COUNT(均线死叉,MACD金叉以来)=1;

{某个条件以来，统计另一个条件出现的次数}{配套代码28};

第29讲

MA1:MA(CLOSE,5);
MA2:MA(CLOSE,10);
MA3:MA(CLOSE,20);
MA4:MA(CLOSE,60);

BOLL:=MA(CLOSE,20);
UB:BOLL+2*STD(CLOSE,20),COLORFF00FF,POINTDOT;
LB:BOLL-2*STD(CLOSE,20),COLORFF00FF,POINTDOT;

第30讲

MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
MA20:=MA(CLOSE,20);
空头排列:=EVERY(MA5<MA10,9) OR EVERY(MA10<MA20,18);
昨日空头排列:=REF(空头排列,1);

大阳线:=C/REF(C,1)>1.08;
站上20日线:=CROSS(C,MA20);
上涨初期:=MA5<MA10 OR CROSS(MA5,MA10);
实体阳线:=H/L>1.045;
XG:昨日空头排列 AND 大阳线 AND 站上20日线 AND 上涨初期 AND 实体阳线;

{配套代码30};

第31讲

MA13:MA(CLOSE,13)COLOR80FFFF;
DRAWTEXT(CURRBARSCOUNT=14,HIGH,'13')COLOR80FFFF;

MA21:MA(CLOSE,21)COLORFF00FF;
DRAWTEXT(CURRBARSCOUNT=22,HIGH,'21')COLORFF00FF;

MA34:MA(CLOSE,34)COLORFFFF00;
DRAWTEXT(CURRBARSCOUNT=35,HIGH,'34')COLORFFFF00;

MA55:MA(CLOSE,55)COLOR00FF00;
DRAWTEXT(CURRBARSCOUNT=56,HIGH,'55')COLOR00FF00;

{配套代码31};

第32讲

DRAWKLINE(H,O,L,C);
MA1:"MA.MA1#WEEK",COLORFFFFFF;
MA2:"MA.MA2#WEEK",COLOR00FFFF;
MA3:"MA.MA1#MONTH",COLORFF00FF;
MA4:"MA.MA2#MONTH",COLORFFFF00;
MA5:"MA.MA1#SEASON",COLOR00FF00;
MA6:"MA.MA2#SEASON",COLORC0C0C0;
MA7:"MA.MA1#YEAR",COLORFF0000;

DRAWTEXT(CURRBARSCOUNT=5,MA1,'5周')COLORFFFFFF;
DRAWTEXT(CURRBARSCOUNT=10,MA2,'10周')COLOR00FFFF;
DRAWTEXT(CURRBARSCOUNT=5,MA3,'5月')COLORFF00FF;
DRAWTEXT(CURRBARSCOUNT=10,MA4,'10月')COLORFFFF00;
DRAWTEXT(CURRBARSCOUNT=5,MA5,'5季')COLOR00FF00;
DRAWTEXT(CURRBARSCOUNT=10,MA6,'10季')COLORC0C0C0;
DRAWTEXT(CURRBARSCOUNT=15,MA7,'5年')COLORFF0000;
{配套代码32}

第33讲

JJX:SUM(C*VOL,0)/SUM(VOL,0),COLOR00FFFF;
DRAWICON(CROSS(C,JJX),C,1);
DRAWICON(CROSS(JJX,C),C,2);
五日线:"MA.MA1#DAY",COLORFF00FF;
{配套代码33};

第34讲

DRAWTEXT_FIX(ISLASTBAR=1,0,0,0,HYBLOCK)COLOR00FFFF;
DRAWTEXT_FIX(ISLASTBAR=1,0.06,0,0,GNBLOCK)COLOR00FF00;
DRAWTEXT_FIX(ISLASTBAR=1,0,0.05,0,FGBLOCK)COLORFF00FF;
{配套代码034};

第35讲
ZSH:=("999999$H");
ZSO:=("999999$O");
ZSL:=("999999$L");
ZSC:=("999999$C");

DRAWKLINE(ZSH,ZSO,ZSL,ZSC);
MA(ZSC,20);

{配套代码0035};

第36讲

ZD1:=MA(CLOSE,30);
ZD2:=MA(CLOSE,40);
ZD3:=MA(CLOSE,48);
ZD4:=MA(CLOSE,60);
ZD5:=MA(CLOSE,80);
ZD6:=MA(CLOSE,96);
ZD7:=MA(CLOSE,90);
ZD8:=MA(CLOSE,120);
ZD9:=MA(CLOSE,144);

MAX1:MAX(MAX(MAX(MAX(MAX(MAX(MAX(MAX(ZD1,ZD2),ZD3),ZD4),ZD5),ZD6),ZD7),ZD8),ZD9)POINTDOT;

{配套代码00036};

第37讲

涨停:=C/REF(C,1)>1.0992;
涨停以来:=BARSLAST(涨停);
涨停当天低:=REF(L,涨停以来);
XG:EVERY(L>=涨停当天低,涨停以来) AND 涨停以来>=5 AND 涨停以来<=9;
{配套代码-37};

第38讲

最高价:DYNAINFO(5),COLORRED,NODRAW;
最高涨幅:(DYNAINFO(5)/DYNAINFO(3)-1)*100,COLORRED,NODRAW;

最低价:DYNAINFO(6),COLORGREEN,NODRAW;
最低涨幅:(DYNAINFO(6)/DYNAINFO(3)-1)*100,COLORGREEN,NODRAW;

流通市值:FINANCE(40)/100000000,COLORC0C0C0,NODRAW;

上涨家数:DYNAINFO(60),COLORRED,NODRAW;
下涨家数:DYNAINFO(61),COLORGREEN,NODRAW;
涨跌比:DYNAINFO(60)/DYNAINFO(61),COLORC0C0C0,NODRAW;

阳线数:COUNT(C>=O,100),COLORRED,NODRAW;
阴线数:COUNT(C<O,100),COLORGREEN,NODRAW;

{配套代码#38};

第39讲

无

第40讲

MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
MA20:=MA(CLOSE,20);
MA30:=MA(CLOSE,30);
MA60:=MA(CLOSE,60);
MA120:=MA(CLOSE,120);

最大线:=MAX(MAX(MAX(MAX(MAX(MA5,MA10),MA20),MA30),MA60),MA120);
最小线:=MIN(MIN(MIN(MIN(MIN(MA5,MA10),MA20),MA30),MA60),MA120);

粘连:最大线/最小线<1.03;

{PTDM40};

第41讲

H120:=HHV(HIGH,120);
XG:H/H120<1 AND H/H120>0.95 AND HHVBARS(H,120)>60,NODRAW;
STICKLINE(XG=1,H120,H120,18,0),COLORYELLOW;
{配套代码4141};

第42讲

CPX:MA(CLOSE,8)*0.18+MA(CLOSE,30)*0.5+MA(CLOSE,60)*0.32,COLORYELLOW;
向上:=CPX>REF(CPX,1) AND MA(CLOSE,30)>REF(MA(CLOSE,30),1) AND C>CPX AND C>MA(CLOSE,30);
向下:=CPX<=REF(CPX,1) AND MA(CLOSE,30)<=REF(MA(CLOSE,30),1) AND C<CPX AND C<MA(CLOSE,30);

STICKLINE(C>=O,L,H,0,0),COLORYELLOW;
STICKLINE(C>=O,C,O,2,1),COLORYELLOW;
STICKLINE(C<O,L,H,0,0),COLORYELLOW;
STICKLINE(C<O,C,O,2,0),COLORYELLOW;

STICKLINE(C>=O AND 向上,L,H,0,0),COLORRED;
STICKLINE(C>=O AND 向上,C,O,2,1),COLORRED;
STICKLINE(C<O AND 向上,L,H,0,0),COLORRED;
STICKLINE(C<O AND 向上,C,O,2,0),COLORRED;

STICKLINE(C>=O AND 向下,L,H,0,0),COLORCYAN;
STICKLINE(C>=O AND 向下,C,O,2,1),COLORCYAN;
STICKLINE(C<O AND 向下,L,H,0,0),COLORCYAN;
STICKLINE(C<O AND 向下,C,O,2,0),COLORCYAN;

{PTDM4242}

第43讲

涨停:=C/REF(C,1)>1.0992;
{存在涨停:EXIST(涨停,22);}
{统计涨停:COUNT(涨停,22)>=2 AND 涨停 AND NOT(REF(涨停,1));}
上次涨停距今天:=REF(BARSLAST(涨停),1);
条件:涨停 AND 上次涨停距今天>2 AND 上次涨停距今天<22;
{PTDM434343};

第44讲

日K:="KDJ.K#DAY"(9,3,3);
日D:="KDJ.D#DAY"(9,3,3);
DRAWICON(日K>日D,0.5,38);
DRAWICON(日K<日D,0.5,39);
日DIF:="MACD.DIF#DAY"(12,26,9);
日DEA:="MACD.DEA#DAY"(12,26,9);
DRAWICON(日DIF>日DEA,1.5,38);
DRAWICON(日DIF<日DEA,1.5,39);

周K:="KDJ.K#WEEK"(9,3,3);
周D:="KDJ.D#WEEK"(9,3,3);
DRAWICON(周K>周D,2.5,38);
DRAWICON(周K<周D,2.5,39);
周DIF:="MACD.DIF#WEEK"(12,26,9);
周DEA:="MACD.DEA#WEEK"(12,26,9);
DRAWICON(周DIF>周DEA,3.5,38);
DRAWICON(周DIF<周DEA,3.5,39);

月K:="KDJ.K#MONTH"(9,3,3);
月D:="KDJ.D#MONTH"(9,3,3);
DRAWICON(月K>月D,4.5,38);
DRAWICON(月K<月D,4.5,39);
月DIF:="MACD.DIF#MONTH"(12,26,9);
月DEA:="MACD.DEA#MONTH"(12,26,9);
DRAWICON(月DIF>月DEA,5.5,38);
DRAWICON(月DIF<月DEA,5.5,39);

XG:日K>日D AND 日DIF>日DEA AND 周K>周D AND 周DIF>周DEA AND 月K>月D AND 月DIF>月DEA,NODRAW;
NOTEXTX1:-1,COLOR000000;

{配套代码四十四};

第45讲

BIAS:(CLOSE-MA(CLOSE,55))/MA(CLOSE,55)*100;
NOTEXT0:0,POINTDOT;
STICKLINE(BIAS>0,0,BIAS,2,0)COLORRED;
STICKLINE(BIAS<0,0,BIAS,2,0)COLORGREEN;

{配套代码四十五篇};

第46讲

最大量K:=HHVBARS(V,144);
最大量KL:=REF(L,最大量K);
DRAWNUMBER(ISLASTBAR,最大量KL,最大量KL),COLORFF00FF;
STICKLINE(ISLASTBAR,最大量KL,最大量KL,28,0);

最大量KH:=REF(H,最大量K);
DRAWNUMBER(ISLASTBAR,最大量KH,最大量KH),COLORFF00FF;
STICKLINE(ISLASTBAR,最大量KH,最大量KH,28,0);

{配套代码第四十六篇}

第47讲

顶距离现在:=HHVBARS(H,66);
底距离现在:=LLVBARS(L,66);
顶量:=REF(VOL,顶距离现在);
底量:=REF(VOL,底距离现在);

XG:顶距离现在>底距离现在 AND 底量>顶量 AND 底距离现在<=15;

{配套代码第四十七篇};

第48讲

涨停:=C/REF(C,1)>1.0992;
昨涨停:REF(涨停,1);

竞价成交量:=DYNAINFO(15)/O/100;
昨日最大分时量:=REF(HHV(VOL,240),FROMOPEN+1);
XG:竞价成交量>昨日最大分时量;

{配套代码集合竞价48}

第49讲

DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
MACD:=(DIF-DEA)*2;
红柱持续缩小:=EVERY(MACD<REF(MACD,1),5) AND EVERY(MACD>0,5);
红柱放大:=MACD>REF(MACD,1);
XG:红柱放大 AND REF(红柱持续缩小,1);

{PEITAODAIMA49}

第50讲

连阴:=EVERY(CLOSE<OPEN,4);
连跌:=EVERY(CLOSE<REF(CLOSE,1),3);
XG:EXIST(连阴,11) AND EXIST(连跌,11) AND H=HHV(H,11) AND BARSLAST(连阴)<=5 AND
C>MA(CLOSE,120) AND C>MA(CLOSE,250);

{配套代码第五十篇};